// Polygon editor, Jarek Rossignac, June 2005

int count =4;                  // number of control vertices
int cap=128;                    // size of control arrays
int gr=4;                     // number of recursions
int pts=count*round(pow(2,gr));
float Px = 0.0; float Py = 0.0; // current mouse position
int bi=-1;                       // index of selected vertex, -1 if none selected
float[] x = new float [cap]; float[] y = new float [cap];
int [] locked = new int [cap]; int [] vlocked = new int [cap*64]; 
float[] vx = new float [cap*64]; float[] vy = new float [cap*64];    
float[] area = new float [cap*64];    // area changes
float s=0.3, t=0.5;           // parameter for smoothing and subdivision
int menuWidth=200;             // width of menu column
int preserve=1;                // restore nothing, area, perimeter
int paste=0;                  // tracking translation, rotation, scaling
color black = color(0, 0, 0); color red = color(200, 0, 0); color green = color(0, 100, 0); color grey = color(180, 180, 180);
color blue = color(0, 0, 200); color yellow = color(250, 250, 130); color brown = color(150, 100, 50); color orange = color(250, 200, 150);
int nov = 4;                                 // number of original vertices
int method=10;
int showDots=1;

float[] ox = new float [cap*round(pow(2,7))]; float[] oy = new float [cap*round(pow(2,7))];
float[] ax = new float [cap*round(pow(2,7))]; float[] ay = new float [cap*round(pow(2,7))];
float[] atx = new float [cap*round(pow(2,7))]; float[] aty = new float [cap*round(pow(2,7))];
float[] artx = new float [cap*round(pow(2,7))]; float[] arty = new float [cap*round(pow(2,7))];
float[] asrtx = new float [cap*round(pow(2,7))]; float[] asrty = new float [cap*round(pow(2,7))];


void setup() { 
    size(600+menuWidth, 600);          // window size 
    PFont font = loadFont("Courier-14.vlw"); textFont(font, 12);
    strokeJoin(ROUND); strokeCap(ROUND);
    for (int i=0; i<count; i++) {x[i]=cos(i*TWO_PI/count)*(200)+300; y[i]=sin(i*TWO_PI/count)*(200)+300;};
    }

void draw() {  
    background(255);
    drawMenu();
    if (bi>-1) {x[bi]=mouseX; y[bi]=mouseY;};                    // snap selected vertex to mouse position during dragging
     switch(method) {
     case 7: QuadricBspline(); break;
     case 8: CubicBspline(); break;
     case 9: FourPoints(); break;
     case 10: Jarek(); break;
     case 11: VariableJarek(); break;
     case 12: LaplaceSmoothing(); break;
     case 13: biLaplaceSmoothing(); break;
     case 14: TaubinSmoothing(); break;
     case 15: LaplacePasting(); break;
     case 16: biLaplacePasting(); break;
     case 17: TaubinPasting(); break;
      };
    drawCurve();
    drawControl();
    } 
    
void drawControl() {
    stroke(brown); strokeWeight(1.0); beginShape(LINE_STRIP);  for (int i=0; i<count; i++) {vertex(x[i], y[i]);} vertex(x[0], y[0]); endShape(); // draw closed loop (notice last vertex 
    strokeWeight(5.0);  beginShape(POINTS);  for (int i=0; i<count; i++) {vertex(x[i], y[i]);} endShape(); // draw large dots at control vertices
    if (showDots==1) {strokeWeight(3.0);  beginShape(POINTS);  for (int i=0; i<count; i++) {vertex((x[i]+x[n(i)])/2, (y[i]+y[n(i)])/2);}; endShape();}; // draw smaller mid-edge dots
    stroke(red); strokeWeight(5.0);  beginShape(POINTS);  for (int i=0; i<count; i++) {if (locked[i]==1) {vertex(x[i], y[i]);}; }; endShape(); // draw smaller mid-edge 
    stroke(black); strokeWeight(1.0); 
  }
  
void drawCurve() {    
     stroke(green); strokeWeight(2.0);  beginShape(LINE_STRIP);  for (int i=0; i<pts; i++) {vertex(vx[i], vy[i]);} vertex(vx[0], vy[0]); endShape(); // draw closed loop (notice last vertex 
     if (showDots==1) {strokeWeight(4.0);  beginShape(POINTS);  for (int i=0; i<pts; i++) {vertex(vx[i], vy[i]);}; endShape(); };  // draw smaller mid-edge dots
     };

void keyPressed() {  
    if (key=='c') {                                                                      // centers the control polygon
     float sx=600.0; float sy=600.0; float bx=0.0; float by=0.0; 
     for (int i=0; i<count; i++) {
         if (x[i]>bx) {bx=x[i];}; if (x[i]<sx) {sx=x[i];}; if (y[i]>by) {by=y[i];}; if (y[i]<sy) {sy=y[i];}; };
         float m=max(bx-sx,by-sy);
         float dx=(m-(bx-sx))/2; float dy=(m-(by-sy))/2;
     for (int i=0; i<count; i++) {x[i]=(x[i]-sx+dx)*400/m+100;  y[i]=(y[i]-sy+dy)*400/m+100;  };
     };
  if (key=='o') {                          // axis aligns the edges
      for (int i=0; i<count; i++) {
         if ( abs(x[n(i)]-x[i])>abs(y[n(i)]-y[i])) {float dy=(y[n(i)]-y[i])/2; y[n(i)]-=dy; y[i]+=dy;}
          else {float dx=(x[n(i)]-x[i])/2; x[n(i)]-=dx; x[i]+=dx;}
         };
     };
  if (key=='v') {println("Control polyloop has "+count+" points"); for (int i=0; i<count; i++) {println(x[i]+ ", " + y[i]); };  println(); }; // print coordinates
  if (key=='w') {println("Derived polyloop has "+pts+" points"); for (int i=0; i<pts; i++) {println(vx[i]+ ", " + vy[i]); }; println(); }; // print coordinates
  if (key=='i') { saveFrame("Loop-####.tif");};                                                         // saves tif image 
  if (key=='d') { showDots=1-showDots;};                                                         // saves tif image 
   };

void drawMenu() {
    String iterlist;
    int j=3;
    fill(yellow);  rect(600, 0, menuWidth, 600);
    if ((6<method)&&(method<18)) { fill(orange); rect(600, 25*(method+3), menuWidth, 25);};
    stroke (green); strokeWeight(1.0); for (int i=25; i<600; i+=25) {line(600,i,600+menuWidth,i);} 
    line(600+menuWidth/6,0,600+menuWidth/6,75);  line(600+2*menuWidth/6,0,600+2*menuWidth/6,75);      
    line(600+4*menuWidth/6,0,600+4*menuWidth/6,75);  line(600+5*menuWidth/6,0,600+5*menuWidth/6,75);  
    fill(black);   
    text("/2", 605,17);  text("-0.1", 605+menuWidth/6,17);  text("s="+str(round(10*s)/10.0), 605+2*menuWidth/6,17);    text("+0.1", 605+4*menuWidth/6,17); text("*2", 605+5*menuWidth/6,17);
    text("/2", 605,17+25);  text("-0.1", 605+menuWidth/6,17+25);  text("t="+str(round(10*t)/10.0), 605+2*menuWidth/6,17+25);    text("+0.1", 605+4*menuWidth/6,17+25); text("*2", 605+5*menuWidth/6,17+25);
    text("/2", 605,17+50);  text("-1", 605+menuWidth/6,17+50);  text("gr="+str(gr), 605+2*menuWidth/6,17+50);    text("+1", 605+4*menuWidth/6,17+50); text("*2", 605+5*menuWidth/6,17+50);
    text("Load", 605,15+25*j++);
    text("Replicate", 605,15+25*j++);
    text("Split", 605,15+25*j++);
    text("Dual", 605,15+25*j++);
    text("Kill", 605,15+25*j++);
    text("Measure all", 605,15+25*j++);
    text("Apply(s,t)", 605,15+25*j++);
    fill(red);
    text("Sub: Quadratic Bspline", 605,15+25*j++);
    text("Sub: Cubic Bspline", 605,15+25*j++);
    text("Sub: Four points", 605,15+25*j++);
    text("Sub: Jarek(s)", 605,15+25*j++);
    text("Sub: Variable Jarek", 605,15+25*j++);
    fill(blue);
    text("Smooth: Laplace", 605,15+25*j++);
    text("Smooth: Bi-laplace", 605,15+25*j++);
    text("Smooth: Taubin(s,t)", 605,15+25*j++);
    fill(green);
    text("Paste: Laplace", 605,15+25*j++);
    text("Paste: Bi-laplace", 605,15+25*j++);
    text("Paste: Taubin", 605,15+25*j++);
    fill(orange); rect(600+(preserve+2)*menuWidth/5, 25*22, menuWidth/5, 25); rect(600+(paste+2)*menuWidth/5, 25*23, menuWidth/5, 25);
    fill(brown);
    line(600+2*menuWidth/5,600,600+2*menuWidth/5,525); line(600+3*menuWidth/5,600,600+3*menuWidth/5,525);  line(600+4*menuWidth/5,600,600+4*menuWidth/5,525);  
    text("Save:", 605,15+25*j); text("ctr", 605+2*menuWidth/5,15+25*j);  text("new", 605+3*menuWidth/5,15+25*j++);
    text("Preserve:", 605,15+25*j); text("no", 605+2*menuWidth/5,15+25*j);  text("area", 605+3*menuWidth/5,15+25*j); text("len", 605+4*menuWidth/5,15+25*j++);
    text("Paste:", 605,15+25*j); text("tra", 605+2*menuWidth/5,15+25*j);  text("rot", 605+3*menuWidth/5,15+25*j); text("sca", 605+4*menuWidth/5,15+25*j++);
    }
    
void mousePressed() {                         // to do when mouse is pressed  
  float bd=600*600;                            // init square of smallest distance to selected point
  Px=mouseX;   Py=mouseY;                     // save current mouse location
  for (int i=0; i<count; i++) {if (d2(i)<bd) {bd=d2(i); bi=i;};};    // select closeest vertex
  if (bd>100) {                               // if closest vertex is too far
      bd=600*600;                             // reinitilize distance squared
      for (int i=0; i<count; i++) {if (dm(i)<bd) {bd=dm(i); bi=i;};}; // closest mid-edge point
      if (bd<1000) {                        // if close enough
          for (int i=count-1; i>bi; i--) {x[i+1]=x[i]; y[i+1]=y[i]; };  // shift down the rest 
          bi++;  x[bi]=Px; y[bi]=Py; count++;  // insert new vertex at mouse position
        }else {bi=-1;};                        // nothing selected
      };
  }

void mouseReleased() {                    // do this when mouse released
  if ((bi!=-1) && ((x[bi]<0)||(x[bi]>600)||(y[bi]<0)||(y[bi]>600))) { // if outside of port
      for (int i=bi; i<count; i++) {x[i]=x[n(i)]; y[i]=y[n(i)]; };  // shift up to delete selected vertex
      count--; };                                                    // reduce vertex count
  if (key=='q') {locked[bi]=1; println("Locked vertex "+bi);};
  bi=-1;                                                           // reset selected vertex id to NIL
    if ((mouseX>600)&&(mouseX<600+menuWidth)) {
    if ((mouseY>0)&&(mouseY<75)){
    println("variable ");
    if ((mouseY>0)&&(mouseY<25)) {switch ((mouseX-600)*6/menuWidth) {case 0: s/=2; break; case 1: s-=0.1; break;  case 4: s+=0.1; break; case 5: s*=2; break;};s=round(10*s)/10.0;};
    if ((mouseY>25)&&(mouseY<50)) {switch ((mouseX-600)*6/menuWidth) {case 0: t/=2; break; case 1: t-=0.1; break;  case 4: t+=0.1; break; case 5: t*=2; break;};t=round(10*t)/10.0;};
    if ((mouseY>50)&&(mouseY<75)) {switch ((mouseX-600)*6/menuWidth) {case 0: gr/=2; break; case 1: gr--; break;  case 4: gr++; break; case 5: gr*=2; break;};};
    }
  else {
    print("choice "+(mouseY-75)/25+" : ");
   switch ((mouseY-75)/25) {
     case 0: loadControl(); println("Loaded "+count+" vertices"); break;
     case 1: replicate(); println("Replicate "+pts+" control points");  method=0; break;
     case 2: splitEdges(); println("Split producing "+pts+" vertices"); break;
     case 3: dual(); println("Dual "); break;
     case 4: kill(); println("Kill "); break;
     case 5: measure(); println("Measure "); break;
     case 6: println("Apply("+s+","+t+")"); break;
     case 7: method=7; println("Quadric Bspline "); break;
     case 8: method=8; println("Cubic Bspline "); break;
     case 9: method=9; println("Four Points "); break;
     case 10: method=10; println("Jarek("+s+")"); break;
     case 11: method=11; println("Variable Jarek "); break;
     case 12: method=12; println("Laplace smoothing"); break;
     case 13: method=13; println("bi-Laplace smoothing "); break;
     case 14: method=14; println("Taubin Smoothing ("+s+","+t+")"); break;
     case 15: method=15; println("Laplace Tracking"); break;
     case 16: method=16; println("BiLaplace Tracking "); break;
     case 17: method=17; println("Taubin Tracking ("+s+","+t+")"); break;
     case 18: print("Save "); 
              switch ((mouseX-600)*5/menuWidth) {case 0: case 1: break;  
              case 2: println("control"); saveControl(); break; 
              case 3: println("derived"); saveDerived(); break; case 4: break;};
              break;
     case 19: print("Preserve ");
              switch ((mouseX-600)*5/menuWidth) {case 0: case 1: break;  
                case 2: print("nothing: "); preserve=0; break; 
                case 3: print("area: "); preserve=1; break; 
                case 4: print("perimeter: "); preserve=2; break;}; 
              println(preserve);
              break;
     case 20: print("Paste "); 
              switch ((mouseX-600)*5/menuWidth) {case 0: case 1: break;  
              case 2: print("tranlsation: "); paste=0; break; 
              case 3: print("rotation: "); paste=1; break; 
              case 4: print("scaling: "); paste=2; break;};
              println(paste);
              break;       
      };
     };
    };
  }
  
void measure() {  L(); L2(); saveL();  }
  
void L() {for (int i=0; i<pts; i++) {ax[i]=(vx[vp(i)]+vx[vn(i)])/2.0-vx[i]; ay[i]=(vy[vp(i)]+vy[vn(i)])/2.0-vy[i]; }; };

void L2() {for (int i=0; i<pts; i++) {atx[i]=(ax[vp(i)]+ax[vn(i)])/2-ax[i]; aty[i]=(ay[vp(i)]+ay[vn(i)])/2-ay[i]; }; };

void saveL () {
  for (int i=0; i<pts; i++) {atx[i]=ax[i];  aty[i]=ay[i];  };
  for (int i=0; i<pts; i++) { 
   float abx=vx[vn(i)]-vx[vp(i)]; float aby=vy[vn(i)]-vy[vp(i)]; float normab=sqrt(abx*abx+aby*aby);
    artx[i]=(ax[i]*abx + ay[i]*aby)/normab;  arty[i]=(-ax[i]*aby + ay[i]*abx)/normab;  
    };
  for (int i=0; i<pts; i++) {
    float abx=vx[vn(i)]-vx[vp(i)]; float aby=vy[vn(i)]-vy[vp(i)]; float normab=abx*abx+aby*aby;
    asrtx[i]=(ax[i]*abx + ay[i]*aby)/normab;  asrty[i]=(-ax[i]*aby + ay[i]*abx)/normab;    
    }; 
  };
 
void M (float ss) {for (int i=0; i<pts; i++) {vx[i]+=ss*ax[i];  vy[i]+=ss*ay[i]; }; };

void M2(float s) {for (int i=0; i<pts; i++) {vx[i]+=s*atx[i]; vy[i]+=s*aty[i]; }; };

void rA (float s) {
  for (int i=0; i<pts; i++) {
    area[i]=s*( ay[i]*(vx[vn(i)]-vx[vp(i)]) - ax[i]*(vy[vn(i)]-vy[vp(i)]) )/2.0;
//   if (area[i]>0) {fill(green);} else {fill(red);}; rect(vx[i],vy[i],sqrt(abs(area[i])),sqrt(abs(area[i])));
     }; 
   };

void MA () {
  for (int i=0; i<pts; i++) {
    float aa=(area[vp(i)]+area[vn(i)])/2.0;
    float bx=vx[vn(i)]-vx[vp(i)]; float by=vy[vn(i)]-vy[vp(i)];
    float b2=sq(bx)+sq(by);
    if (abs(b2)<100.0) { 
    bx=vx[vn(vn(i))]-vx[vp(vp(i))]; by=vy[vn(vn(i))]-vy[vp(vp(i))]; b2=sq(bx)+sq(by);
    fill(brown); ellipse(vx[i],vy[i],10.0,10.0);
    };
    float ss=0.0;
    if (abs(b2)>100.0)  {ss=-2*aa/b2;} else {fill(red); ellipse(vx[i],vy[i],10.0,10.0);};
     vx[i]+=-ss*by;  vy[i]+=ss*bx; 
     }; 
   };

void loadControl() {
  String [] ss = loadStrings("loop.txt");
  String subpts;
  int s=0;
  int comma;
  count = int(ss[s]);
  for(int i=0;i<count; i++) {
      comma=ss[++s].indexOf(',');
      x[i]=float(ss[s].substring(0, comma)); y[i]=float(ss[s].substring(comma+1, ss[s].length()));
    };
  };

void replicate() { pts=count; for (int i=0; i<pts; i++) {vx[i]=x[i]; vy[i]=y[i];}; };  //  pts=count*round(pow(2,gr));

void splitEdges() {for (int i=pts-1; 0<=i; i--) {vx[2*i+1]=(vx[i]+vx[vn(i)])/2; vx[2*i]=vx[i]; vy[2*i+1]=(vy[i]+vy[vn(i)])/2; vy[2*i]=vy[i]; }; pts=2*pts; };

void dual() {float sx=(vx[0]+vx[pts-1])/2; float sy=(vy[0]+vy[pts-1])/2; for (int i=0; i<pts-1; i++) {vx[i]=(vx[i]+vx[i+1])/2; vy[i]=(vy[i]+vy[i+1])/2;}; vx[pts-1]=sx; vy[pts-1]=sy;};

void kill() {for (int i=0; i<pts/2; i++) {vx[i]=vx[2*i+1]; vy[i]=vy[2*i+1];}; pts=pts/2; };

void QuadricBspline() {  replicate (); for (int i=0; i<gr; i++) { splitEdges(); dual();};  }

void CubicBspline() {  replicate (); for (int i=0; i<gr; i++)  { splitEdges(); L(); M(0.5);};  }  //  { splitEdges(); dual(); dual();};
void FourPoints() {replicate (); for (int i=0; i<gr; i++) { splitEdges(); L(); M(0.5); L(); M(-1.0); };}
void Jarek() {replicate (); for (int i=0; i<gr; i++) {J(s);};};    // { splitEdges(); L(); L2(); M(1/2.0-s); M2(-s/2.0); }; // splitEdges(); L(); M(0.5); L(); M(-0.5);};
void VariableJarek() {replicate(); if (gr>0){J(1.0);}; if (gr>1){J(0.0);}; if (gr>2){J(-1.0);} for (int i=3; i<gr; i++) { J(-2.0);}; };
//void J (float s) {splitEdges(); L(); M(0.5); L(); M(-s); };
void J (float s) {splitEdges(); L();  if (preserve==1) {rA(s); M(s); L(); MA();} else {M(0.5); L(); M(-s);}; };
////////// ****************************

void LaplaceSmoothing() { replicate (); for (int i=0; i<gr; i++) { L(); M(0.10); }; }

void biLaplaceSmoothing() { replicate (); for (int i=0; i<gr; i++) { L(); L2(); M2(-2.0/9.0); };  }

void TaubinSmoothing() { replicate (); for (int i=0; i<gr; i++) { L(); M(s); L(); M(-t); }; }
//void RTaubin() {float alph=mouseX/1200.0; float beta=mouseY/1200.0;  for (int i=0; i<sr; i++) { laplace(); xmove(alph-beta); laplace(); xmove(-alph*beta); }; };

void LaplacePasting() {if (locked[0]==1) {}; }

void biLaplacePasting() {}

void TaubinPasting() {replicate (); for (int i=0; i<gr; i++) { L(); L2(); M2(-2.0/9.0); L(); L2(); M2(0.2); }; }
 
void saveControl() {
  String [] inppts = new String [count+1];
  int s=0;
  inppts[s++]=str(count);
  for (int i=0; i<count; i++) {inppts[s++]=str(x[i])+","+str(y[i]);};
  saveStrings("loop.txt",inppts);
  };

void saveDerived() {
  String [] inppts = new String [pts+1];
  int s=0;
  inppts[s++]=str(pts);
  for (int i=0; i<pts; i++) {inppts[s++]=str(vx[i])+","+str(vy[i]);};
  saveStrings("loop.txt",inppts);
  };
   
int n(int j) {  if (j==count-1) {return (0);}  else {return(j+1);}  };  // next vertex in control loop
int vn(int j) {  if (j==pts-1) {return (0);}  else {return(j+1);}  };  // next vertex in subdivided loop
int vp(int j) {  if (j==0) {return (pts-1);}  else {return(j-1);}  };  // previous vertex in subdivided loop
float d2(int j) {return (x[j]-Px)*(x[j]-Px)+(y[j]-Py)*(y[j]-Py);};   //  squared distance to vertex
float dm(int j) {return ((x[j]+x[n(j)])/2-Px)*((x[j]+x[n(j)])/2-Px)    // squared distance to mid-edge point
                       +((y[j]+y[n(j)])/2-Py)*((y[j]+y[n(j)])/2-Py);};