// Project P1 for CS1050: Truth table plotter 
// Written by  Prof. Jarek Rossignac 
// Completed on December 15. 2005

// Declaration and initialization of global variables
PFont fontUsed;                         // name of font used for writing numbers on the graphic screen
int W=8, H=32;                         // width (number of colums) and height (number of rows) of the table
int T[][] = new int[H][W];              // two dimensional table (array). Will containintegers
boolean TF[][] = new boolean[H][W];     // two dimensional table (array). Will contain booleans
color myRed = color(250,100,100);  color myGreen = color(100,250,100); // my colors (R,G,B) in [0,255]
int cw, ch;                             // cell witdh and height

//***************
//***  SETUP  ***
//***************
void setup() {           // executed only once as initialization
  size(500, 750);        // opens graphic window of 600x600 pixels. X axis goes right, Y axis goes DOWN
  cw=int(0.9*width/W);            // computes cell sizes leaving a margin, Cast to integer
  ch=int(0.9*height/H);           // (height and width of window are keywords) 
  fontUsed = loadFont("Times-Roman-25.vlw");  // this font must be loaded (MENU-BAR > TOOLS > CREATE FONTS)
  textFont(fontUsed, 12);                     // selects font and assigns size
  };                    // end of setup
  
//***************
//***  DRAW  ***
//***************
void draw() {          // will be executed continuously to refresh the window many frames per second
  background(200);     // erases the screen and set up a light grey background (0 is black, 255 is white)
  strokeWeight(2);     // lines will be drawn thicker
  translate(width*0.05,height*0.05);        // move the origin to leave a margin 
  ShowTruthTable();     // Defined below: does all the work
  noLoop();            // stop refreshing window
  };                   // end of draw
        
//**********************************
//***  RESPOND TO CONTROL WITH KEYS
//**********************************
void keyPressed() {                                // executed when a key is pressed
  if (key=='i') { saveFrame("squares-####.tif");};   // saves a tif image of the window in the folder of this file
    };
       
//**********************************
//***  COMPUTE AND DRAW TRUTH TABLE
//**********************************    
void ShowTruthTable() {
  color cellColor = myGreen;                 // set cellColor to default green
  int v=0;                            // current value, will be incremented as we scan the table
  byte B;                             // byte equivalent of v
  String S;                           // string used to extract the bits of B
  boolean P[] = new boolean [8];      // table of Booleans corresponding to these bits
   for (int h=0; h<H; h++) {           // scan the rows using integer h
     for (int w=0; w<W; w++) {       // scan the entries in each row using integer w 
        T[h][w]=v;                  // store integer value to be dislayed in cell
        B=byte(v % 256);            // converts to a byte using modulo
        S=binary(B);                // extracts bits into a string
        for (int j=0; j<S.length(); j++) { P[j] = S.charAt(j) == '1'; };  // sets T/F values for each bit into P
        if (expression(P[0],P[1],P[2],P[3],P[4],P[5],P[6],P[7]))   // test expression
          {cellColor = myGreen;}                                   // to set color
          else {cellColor = myRed; };      
        drawCell(w*cw,h*ch,cw,ch,cellColor,T[h][w]);      // calls my DrawCell procedure defined delow passing the geometry, value, color
        v++;                          // increment v
        };       };                        // end of double loop
    };
  
// Draw a cell and print its value 
void drawCell(int wp, int hp, int cwp, int chp, color cp, int vp) { // will draw cell (position, size, color, text)
  fill(cp);                              // set color to be used for filling in regions
  rect(wp,hp,cwp,chp);                  // draws and fills a rectangular region
  fill(0);                             // to write in black
  text(binary(vp,8),wp+cwp/10,hp+chp*0.8);      // writes vp on the screen
  };
 
// Function evaluating the Boolean expression
boolean expression(boolean A, boolean B, boolean C, boolean D, boolean E, boolean F, boolean G, boolean H) {
   boolean res= A==B==C==D==E==F==G==H;      // *** change this to the desired proposition
   return(res); 
   };